I have come across a problem that has me perplexed.
The scene below illustrates the problem.  When the scene is rendered with
originally (with photons or without) without radiosity, the dispersion works
correctly for both the photons and for regular dispersion.  However, when I
turn on radiosity and interupt it mid-render something funky happens to the
dispersion.  Turn radiosity back off and rerender with just dispersion.  Now
the dispersion no longer works for either regular or photons. Close POV and
reopen and rerender without radiosity and dispersion has returned!  I have
no clue as to what is causing this (perhaps some sort of memory issue?)
See the images posted in p.b.i for the versions as rendered by me.

My machine: P4, 1GHz, 256 MB RAM, WIN2000 Professional
POV 3.5 for windows (final release)

Does anyone have any idea why or is the a legitimate bug that should be
reported?
Can anyone else confirm?  Perhaps it is platform specific

thanks

-tgq

sample scene:

//start sample scene
#declare Pho = yes;
#declare Rad = no;

#default{finish{ambient 0 diffuse 0.55}}

global_settings {
  adc_bailout 0.00001
  ambient_light 1
  assumed_gamma 1.8
  max_trace_level 50
  #if (Rad)
    radiosity{
      count 500
    }
  #end
  #if (Pho)
    photons{
      count 500000
     radius 1.0
      autostop 0
    }
  #end
}

camera {
  up y
  angle 42
  location <0,5,-18>
  look_at  <0,5,0>
  right x*image_width/image_height
}

light_source {0 rgb 1
  fade_power 2  fade_distance 12
  translate  11*y
  photons{refraction on reflection on}
}

light_source {0 rgb .5
  fade_power 2  fade_distance 12
  translate  5*y
  photons{refraction off reflection off}
}

difference{
  box{-2, 2}
  plane{y 0 rotate z*30 translate x*2}
  plane{-y 0 rotate -z*30 translate x*2}
  plane{-z 0 rotate y*30 translate x*2}
  rotate -z*20 translate y*5
  material{
    texture{
       pigment{rgbf 1}
       finish{diffuse 0.0
          conserve_energy
          reflection {0 1 fresnel on metallic 0}
       }
    }
    interior{
      ior 1.65
      dispersion 1.1
      dispersion_samples 21
      fade_distance 15
      fade_power 1000
    }
  }
  photons{
    target 1
    reflection on
    refraction on
    collect off
  }
}

difference{
  box {<-6, -1, -5>, <6, 13, 6>}
  box {<-5, 0, -6>, <5, 10, 5>}
  box {<-0.01, 9, -0.3>, <0.01,12, 0.3>}
  texture{pigment{checker rgb 0 rgb 1}}
}
//end sample scene

Post a reply to this message